SORACOM IoT レシピ：M5Stackで作る、設定温度で通知が届くIoT水温計

/*
 * Copyright (c) 2020 SORACOM, INC.
 * Released under the MIT license
 * https://opensource.org/licenses/mit-license.php
*/
#include <M5Stack.h>

#define TINY_GSM_MODEM_UBLOX
#include <TinyGsmClient.h>

TinyGsm modem(Serial2); /* 3G board modem */
TinyGsmClient ctx(modem);

void setup() {
  M5.begin();
  M5.Lcd.clear(BLACK);
  M5.Lcd.setTextColor(WHITE);
  M5.Lcd.println(F("M5Stack + 3G Module"));

  M5.Lcd.print(F("modem.restart()"));
  Serial2.begin(115200, SERIAL_8N1, 16, 17);
  modem.restart();
  M5.Lcd.println(F("done"));

  M5.Lcd.print(F("getModemInfo:"));
  String modemInfo = modem.getModemInfo();
  M5.Lcd.println(modemInfo);

  M5.Lcd.print(F("waitForNetwork()"));
  while (!modem.waitForNetwork()) M5.Lcd.print(".");
  M5.Lcd.println(F("Ok"));

  M5.Lcd.print(F("gprsConnect(soracom.io)"));
  modem.gprsConnect("soracom.io", "sora", "sora");
  M5.Lcd.println(F("done"));

  M5.Lcd.print(F("isNetworkConnected()"));
  while (!modem.isNetworkConnected()) M5.Lcd.print(".");
  M5.Lcd.println(F("Ok"));

  M5.Lcd.print(F("My IP addr: "));
  IPAddress ipaddr = modem.localIP();
  M5.Lcd.print(ipaddr);
  delay(2000);
}

void loop() {
  M5.update();

  M5.Lcd.clear(BLACK);
  M5.Lcd.setCursor(0, 0);
  M5.Lcd.println(F("World Clock from worldtimeapi.org"));

  /* HTTP GET example */
  if (!ctx.connect("worldtimeapi.org", 80)) {
    Serial.println(F("Connect failed."));
    return;
  }
  Serial.println(F("connected."));

  /* send request */
  ctx.println("GET /api/timezone/Asia/Tokyo.txt HTTP/1.0");
  ctx.println("Host: worldtimeapi.org");
  ctx.println();
  Serial.println("sent.");

  /* receive response */
  while (ctx.connected()) {
    String line = ctx.readStringUntil('\n');
    Serial.println(line);
    if (line == "\r") {
      Serial.println("headers received.");
      break;
    }
  }
  char buf[1 * 1024] = {0};
  ctx.readBytes(buf, sizeof(buf)); /* body */
  ctx.stop();
  M5.Lcd.println(buf);

  delay(1000 * 10);
}

/*
 * Copyright (c) 2021 SORACOM, INC.
 * Released under the MIT license
 * https://opensource.org/licenses/mit-license.php
*/

#include <M5Stack.h>
#include <HTTPClient.h> // Why? see https://qiita.com/ma2shita/items/97bf1a0c3158b848019a
#define SerialMon Serial
#define TEXT_SIZE 2

#include <OneWire.h>
#include <DallasTemperature.h>


// add this line
#include <Wire.h>


#define ONE_WIRE_BUS 22 

OneWire oneWire(ONE_WIRE_BUS);
DallasTemperature DS18B20(&oneWire);

#include <ArduinoJson.h>
/* Dynamic configuration by SORACOM Air metadata:
 *  example:
{
  "COMMUNICATION_INTERVAL_SEC": 10,
  "LCD_TURN_ON_AT_BOOT": true
}
*/
long COMMUNICATION_INTERVAL_SEC = 10;
bool LCD_TURN_ON_AT_BOOT = true;

#define SerialAT Serial2 // `Serial2` is 3G Extension board for M5Stack Basic/Gray
#define TINY_GSM_MODEM_UBLOX
#include <TinyGsmClient.h>
TinyGsm modem(SerialAT);
TinyGsmClient socket(modem);

template<typename T, typename U> void check_connection_status_also_reconnect(T *modem, U *serialMon) {
  serialMon->println((modem->isGprsConnected()) ? "isGprsConnected(): true" : "isGprsConnected(): false");
  long s = millis();
  if (!modem->isGprsConnected()) {
    serialMon->print(F("modem.restart(): "));
    modem->restart();
    serialMon->println(F("done"));
    serialMon->print(F("getModemInfo(): "));
    serialMon->println(modem->getModemInfo());
    serialMon->print(F("getIMEI(): "));
    serialMon->println(modem->getIMEI());
    serialMon->print(F("waitForNetwork(): "));
    while (!modem->waitForNetwork()) serialMon->print(F("."));
    serialMon->println(F("Ok"));
    serialMon->print(F("gprsConnect(soracom.io): "));
    modem->gprsConnect("soracom.io", "sora", "sora");
    serialMon->println(F("done"));
    serialMon->print(F("isNetworkConnected(): "));
    while (!modem->isNetworkConnected()) serialMon->print(F("."));
    serialMon->println(F("Ok"));
    serialMon->print(F("localIP(): "));
    serialMon->println(modem->localIP());
  }
  long e = millis();
  serialMon->print(F("Modem bootup elapsed(ms): "));
  serialMon->println(e - s);
  serialMon->print(F("getSignalQuality(): "));
  serialMon->println(modem->getSignalQuality());
}

#include <ArduinoHttpClient.h>

template<typename T, typename U> String get_value_of(const char *tag_name, T socket, U *serialMon) {
  char path[255];
  sprintf_P(path, PSTR("/v1/subscriber.tags.%s"), tag_name);
  serialMon->print(F("path="));
  serialMon->println(path);
  HttpClient http = HttpClient(socket, "metadata.soracom.io", 80);
  http.get(path);
  int rc = http.responseStatusCode();
  String rb = http.responseBody();
  http.stop();
  serialMon->print(F("responseStatusCode(): "));
  serialMon->println(rc);
  serialMon->print(F("responseBody(): "));
  serialMon->println(rb);
  if (rc != 200) rb = "";
  return rb;
}

template<typename T, typename U> void send_to_cloud(const char *upstream_payload, T socket, U *serialMon) {
  serialMon->println(upstream_payload);
  HttpClient http = HttpClient(socket, "uni.soracom.io", 80);
  http.post("/", "application/json", upstream_payload);
  serialMon->print(F("responseStatusCode(): "));
  serialMon->println(http.responseStatusCode());
  http.stop();
}


bool lcd_status = LCD_TURN_ON_AT_BOOT;
bool using_cloud = true;

#include <Ticker.h>
Ticker ticker1;

volatile long count = 0;
void countdown_ticker_for_communication() {
  count--;
  if (count < 0) count = 0; // Avoiding minus
}

void reset_count() {
  count = COMMUNICATION_INTERVAL_SEC - 1; // Zero origin
}

void setup() {
  M5.begin();
  SerialAT.begin(115200, SERIAL_8N1, 16, 17);

  
  M5.Lcd.fillScreen(TFT_BLACK);
  M5.Lcd.setTextSize(TEXT_SIZE);
  M5.Lcd.setCursor(0, 0);
  SerialMon.println(F("Boot..."));
  M5.Lcd.println(F("Boot..."));
  
  M5.update();
  if (M5.BtnA.isPressed()) {
    SerialMon.println(F("Skip fetching config from Cloud"));
    M5.Lcd.println(F("Skip fetching config from Cloud"));
    delay(2000);
    using_cloud = false;
  }
  
  const size_t capacity = JSON_OBJECT_SIZE(6) + 140; // Code generate by https://arduinojson.org/v6/assistant/
  DynamicJsonDocument doc(capacity);  
  if (using_cloud) {
    SerialMon.println(F("Trying fetch config from Cloud (Wait about 50 seconds..."));
    M5.Lcd.println(F("Trying fetch config from Cloud (Wait about 50 seconds..."));
    check_connection_status_also_reconnect(&modem, &SerialMon);
    String tag_value = get_value_of("config_json", socket, &SerialMon);
    DeserializationError err = deserializeJson(doc, tag_value);
    if (err) {
      SerialMon.print(F("deserializeJson() failed: "));
      SerialMon.println(err.c_str());
      SerialMon.println(F("(But ignored.)"));
    }
  }
  
  // Load value from JSON or set default
  COMMUNICATION_INTERVAL_SEC = doc["COMMUNICATION_INTERVAL_SEC"] | COMMUNICATION_INTERVAL_SEC;
  LCD_TURN_ON_AT_BOOT = doc["LCD_TURN_ON_AT_BOOT"] | LCD_TURN_ON_AT_BOOT;
  
  if (LCD_TURN_ON_AT_BOOT) {
    M5.Lcd.wakeup();
    M5.Lcd.setBrightness(255);
  } else {
    M5.Lcd.sleep();
    M5.Lcd.setBrightness(0);
  }
  
  M5.Lcd.fillScreen(TFT_BLACK); // for clear
  M5.Lcd.fillRect(0, M5.Lcd.fontHeight() * 0, M5.Lcd.width(), M5.Lcd.fontHeight() * 1, TFT_DARKGREY); // 0means 0row
  M5.Lcd.setTextColor(TFT_WHITE);
  M5.Lcd.setTextDatum(TL_DATUM);
  M5.Lcd.drawString("Config", 0, 0);
  
  M5.Lcd.setCursor(0, M5.Lcd.fontHeight() * 1); // 1means 1row
  M5.Lcd.setTextColor(TFT_WHITE);
  M5.Lcd.printf("Communication Int.(s): %3u\r\n", COMMUNICATION_INTERVAL_SEC);
  M5.Lcd.print("Trun ON LCD at boot: "); M5.Lcd.println((LCD_TURN_ON_AT_BOOT) ? "true" : "false");
  
  M5.Lcd.fillRect(0, M5.Lcd.fontHeight() * 6, M5.Lcd.width(), M5.Lcd.fontHeight() * 1, TFT_DARKGREEN); // 6means 6row
  M5.Lcd.setTextColor(TFT_WHITE);
  M5.Lcd.setTextDatum(TL_DATUM);
  M5.Lcd.drawString("Current Status", 0, M5.Lcd.fontHeight() * 6); // 6means 6row

  reset_count();
  ticker1.attach_ms(1000, countdown_ticker_for_communication);
}

void loop() {
  float celsius;
  M5.update();
  
  if (M5.BtnC.wasReleased()) {
    if (lcd_status) {
      M5.Lcd.sleep();
      M5.Lcd.setBrightness(0);
    } else {
      M5.Lcd.wakeup();
      M5.Lcd.setBrightness(255);
    }
    lcd_status = !lcd_status;
  }

  DS18B20.begin();
  int device_count = DS18B20.getDS18Count();
  DS18B20.requestTemperatures();
  celsius = DS18B20.getTempCByIndex(0);
  
  M5.Lcd.fillRect(0, M5.Lcd.fontHeight() * 7, M5.Lcd.textWidth("Temperature: nn.n C"), M5.Lcd.fontHeight() * 1, TFT_BLACK); // 7means 7row
  M5.Lcd.setTextColor(TFT_WHITE);
  M5.Lcd.setTextDatum(TL_DATUM);
  M5.Lcd.setCursor(0, M5.Lcd.fontHeight() * 7); // 7means 7row
  M5.Lcd.printf("Temperature: %2.1f C\r\n", celsius);

  if(using_cloud) {
    SerialMon.print(F("countdown: ")); SerialMon.println(count);
    M5.Lcd.fillRect(0, M5.Lcd.fontHeight() * 9, M5.Lcd.textWidth("Communicate After: 9999s"), M5.Lcd.fontHeight() * 1, TFT_BLACK); // 9means 9row
    M5.Lcd.setTextColor(TFT_WHITE);
    M5.Lcd.setTextDatum(TL_DATUM);
    M5.Lcd.setCursor(0, M5.Lcd.fontHeight() * 9); // 9means 9row
    M5.Lcd.printf("Communicate After: %4u s\r\n", count);
    
      if (count == 0) {
      M5.Lcd.fillRect(0, M5.Lcd.fontHeight() * 10, M5.Lcd.textWidth("Send to cloud..."), M5.Lcd.fontHeight() * 1, TFT_BLACK); // 10means 10row
      if (device_count == 0) {
        SerialMon.println(F("No device found"));
        M5.Lcd.setTextColor(TFT_MAROON);
        M5.Lcd.setTextDatum(TL_DATUM);
        M5.Lcd.drawString("No device found", 0, M5.Lcd.fontHeight() * 10); // 10means 10row
        delay(3000);
      } else {
        SerialMon.println(F("Send to cloud..."));
        M5.Lcd.setTextColor(TFT_CYAN);
        M5.Lcd.setTextDatum(TL_DATUM);
        M5.Lcd.drawString("Send to cloud...", 0, M5.Lcd.fontHeight() * 10); // 10means 10row
        const size_t capacity = JSON_OBJECT_SIZE(1); // Code generate by https://arduinojson.org/v6/assistant/
        DynamicJsonDocument doc(capacity);
        doc["temp"] = celsius;
        char upstream_payload[512];
        serializeJson(doc, upstream_payload);
        if (using_cloud) {
          check_connection_status_also_reconnect(&modem, &SerialMon);
          send_to_cloud(upstream_payload, socket, &SerialMon);
        }
      }
      M5.Lcd.fillRect(0, M5.Lcd.fontHeight() * 10, M5.Lcd.textWidth("Send to cloud..."), M5.Lcd.fontHeight() * 1, TFT_BLACK); // 10means 10row
      reset_count();
    }
  }
}

{
    "annotations": {
      "list": [
        {
          "builtIn": 1,
          "datasource": "-- Grafana --",
          "enable": true,
          "hide": true,
          "iconColor": "rgba(0, 211, 255, 1)",
          "name": "Annotations & Alerts",
          "type": "dashboard"
        }
      ]
    },
    "editable": true,
    "gnetId": null,
    "graphTooltip": 0,
    "id": 19,
    "links": [],
    "panels": [
      {
        "alert": {
          "alertRuleTags": {},
          "conditions": [
            {
              "evaluator": {
                "params": [
                  33
                ],
                "type": "gt"
              },
              "operator": {
                "type": "and"
              },
              "query": {
                "params": [
                  "A",
                  "1m",
                  "now"
                ]
              },
              "reducer": {
                "params": [],
                "type": "last"
              },
              "type": "query"
            }
          ],
          "executionErrorState": "keep_state",
          "for": "0m",
          "frequency": "1m",
          "handler": 1,
          "message": "",
          "name": "M5Stack OneWire alert",
          "noDataState": "no_data",
          "notifications": [
            {
              "uid": "jUA38eeGk"
            }
          ]
        },
        "aliasColors": {},
        "bars": false,
        "dashLength": 10,
        "dashes": false,
        "datasource": null,
        "fieldConfig": {
          "defaults": {
            "custom": {}
          },
          "overrides": []
        },
        "fill": 1,
        "fillGradient": 0,
        "gridPos": {
          "h": 8,
          "w": 12,
          "x": 0,
          "y": 0
        },
        "hiddenSeries": false,
        "id": 2,
        "legend": {
          "avg": false,
          "current": false,
          "max": false,
          "min": false,
          "show": true,
          "total": false,
          "values": false
        },
        "lines": true,
        "linewidth": 1,
        "nullPointMode": "null",
        "options": {
          "alertThreshold": true
        },
        "percentage": false,
        "pluginVersion": "7.5.0-pre",
        "pointradius": 2,
        "points": false,
        "renderer": "flot",
        "seriesOverrides": [],
        "spaceLength": 10,
        "stack": false,
        "steppedLine": false,
        "targets": [
          {
            "datatype": "standard",
            "devicetype": "subscribers",
            "properties": "temp",
            "refId": "A",
            "target": "440103197745415",
            "type": "timeseries"
          }
        ],
        "thresholds": [
          {
            "colorMode": "critical",
            "fill": true,
            "line": true,
            "op": "gt",
            "value": 33,
            "visible": true
          }
        ],
        "timeFrom": null,
        "timeRegions": [],
        "timeShift": null,
        "title": "M5Stack OneWire",
        "tooltip": {
          "shared": true,
          "sort": 0,
          "value_type": "individual"
        },
        "type": "graph",
        "xaxis": {
          "buckets": null,
          "mode": "time",
          "name": null,
          "show": true,
          "values": []
        },
        "yaxes": [
          {
            "format": "short",
            "label": null,
            "logBase": 1,
            "max": null,
            "min": null,
            "show": true
          },
          {
            "format": "short",
            "label": null,
            "logBase": 1,
            "max": null,
            "min": null,
            "show": true
          }
        ],
        "yaxis": {
          "align": false,
          "alignLevel": null
        }
      }
    ],
    "refresh": "10s",
    "schemaVersion": 27,
    "style": "dark",
    "tags": [],
    "templating": {
      "list": []
    },
    "time": {
      "from": "now-15m",
      "to": "now"
    },
    "timepicker": {
      "refresh_intervals": [
        "5s",
        "10s",
        "30s",
        "1m",
        "5m",
        "15m",
        "30m",
        "1h",
        "2h",
        "1d"
      ],
      "time_options": [
        "5m",
        "15m",
        "1h",
        "6h",
        "12h",
        "24h",
        "2d",
        "7d",
        "30d"
      ]
    },
    "timezone": "",
    "title": "水温センサー",
    "uid": "",
    "version": 10
  }